как правильно построить фильтр

[S.Kuskov]

Цитата:

Сообщение от timaluhs

[Date values should be formatted using Date2StrXpp() ]

пыталась вместо FromDate.valueStr() - date2strxpp(FromDate) ругается
Argument '_date' ia incompatible with required type.

Аргумент функции date2strxpp должен иметь тип дата. Попробуйте чтото вроде

date2strxpp(FromDate.DateValue())

[timaluhs]

поставила
date2strxpp(FromDate.DateValue())
теперь SQL вообще какой-то кривой

(((((STARTDATE>=01\01\2011) and (STARTDATE<=22\05\2011)) or ((ENDDATE>=01\01\2011) and (ENDDATE<=22\05\2011)))))

[S.Kuskov]

Цитата:

Сообщение от timaluhs

теперь SQL вообще какой-то кривой

Что именно вам не нравится? Если вы про пару лишних внешних скобок, то это нормаьлно

Ещё. Вместо AND и OR используйте && и || соответственно.

[timaluhs]

почему && и || ?это же запрос который идёт на SQL сервер. Там вроде как and и or надо.
и слэши обратные как -то не очень. SQL сервер ругается на такое
"Incorrect syntax near '\01'."
не нравится ему дата в таком виде

[S.Kuskov]

Цитата:

Сообщение от timaluhs

это же запрос который идёт на SQL сервер

Неа. Это запрос, который ещё будет постобработан аксаптой.

Вот такой код у меня выполняется без ошибок:

static void JobTestExpressionsInQueryRanges(Args _args)
{
    InventTrans InventTrans;
    fromDate fromDate   = 03\05\2011;
    toDate  toDate      = 04\05\2011;

    Query q;
    QueryBuildDataSource qbdsInventTrans;
    QueryRun qr;
    ;
    q = new Query();
    qbdsInventTrans = q.addDataSource(tableNum(InventTrans));
    qbdsInventTrans.addRange(fieldNum(InventTrans, RecId)).value(
        strfmt("(((%1.%2 >= %4) && (%1.%2 <= %5)) || ((%1.%3 >= %4) && (%1.%3 <= %5)))" ,
            qbdsInventTrans.name(),
            fieldStr(InventTrans, DatePhysical),
            fieldStr(InventTrans, DateFinancial),
            Date2StrXpp(fromDate),
            Date2StrXpp(toDate)
        ));

    info(qbdsInventTrans.toString());

    qr = new QueryRun(q);
    while (qr.next())
    {
        InventTrans = qr.get(tableNum(InventTrans));
        info(InventTrans.ItemId);
        break;
    }

    info(".");
}

Обратите внимание на то, что имя таблицы, а точнее имя источника данных, в данном запросе (в условии участвует поля из одной и той же таблицы) можно было не указывать, но в общем случае его указывать нужно.
Впрочем этот нюанс и многие другие описаны в статье по ссылке, которую я приводил выше

[timaluhs]

исходная дата приходит из календаря на форме
обратные слэши это после date2strxpp и
после info(this.query().dataSourceTable(tableNum(mlm_TemporaryLeaveReport)).toString());и если я правильно понимаю должно быть and а не &&
т.е обратные слеши идут на SQL,а там их явно не ждали

[S.Kuskov]

Цитата:

Сообщение от timaluhs

если я правильно понимаю должно быть and а не &&
т.е обратные слеши идут на SQL

Нет. Ещё раз повторю, на самом деле текст запроса, который вы видите после info(this.query().dataSourceTable(tableNum(mlm_TemporaryLeaveReport)).toString()) ещё НЕ является окончательным вариантом SQL запроса. Аксапта его ещё будет обрабатывать. Сама заменит && и || на AND и OR и сконвертирует формат даты.

[nix0root]

К примеру.

            qbrEmployDate.value(   '(EmplTable.PayEmploymentDate_RU != '+date2StrXpp(datenull())+')'
                                  +'&&'
                                  +'(EmplTable.PayEmploymentDate_RU <= '+date2StrXpp(systemdateget())+')'
                               );
            qbrResignDate.value(   '(EmplTable.PayResignedDate_RU !='+date2StrXpp(datenull())+')'
                                  +'&&'
                                  +'(EmplTable.PayResignedDate_RU < '+date2StrXpp(systemdateget())+')');