можно ли в Аксапте сделать такой Query

[Evgeniy2020]

" либо нет строк с определённой номенклатурой, либо есть неблокированные строки с этой номенклатурой и все они находятся в статусе «открыто»"
=>
нет строк, клоторая блокированна или закрыта?


получается можно перефразировать как

получить
сумма количества в строках закупок для данной номенклатуры
для
всех открытых закупок для данного поставщика,
кроме тех закупок где есть хотя бы одна закрытая или заблокированная
строка с данной номенклатурой.

по идее будет тот же набор записей только через другой запрос.

первый вариант как я понял мжно сделать при помощи union
но в 4-ке и тройке такого типа вроде нет.

вообщем попробую

[titov]

static void PurchLineQuery(Args _args)
{
    QueryBuildDataSource        qbdsPurchLineSum,qbdsPurchTable,qbds;
    QueryBuildRange             qbr;
    Query                       q = new Query();
    QueryRun                    qr;
    PurchLine                   PurchLine;
    #define.itemIdParm('123')
    ;
    qbdsPurchLineSum    = q.addDataSource(tableNum(PurchLine));
    qbdsPurchLineSum.addSelectionField(fieldNum(PurchLine,PurchQty),SelectionField::Sum);//внимание на единицы измерения! может даже лучше идти по inventTrans
    qbr                 = sysQuery::findOrCreateRange(qbdsPurchLineSum,fieldNum(PurchLine,PurchStatus));
    qbr.value(queryValue(PurchStatus::Backorder));
    qbr                 = sysQuery::findOrCreateRange(qbdsPurchLineSum,fieldNum(PurchLine,ItemId));
    qbr.value(queryValue(#itemIdParm));

    qbdsPurchTable      = qbdsPurchLineSum.addDataSource(tableNum(PurchTable));
    qbdsPurchTable.joinMode(joinMode::ExistsJoin);
    qbdsPurchTable.fetchMode(QueryFetchMode::One2One);
    qbdsPurchTable.relations(true);
    qbr                 = sysQuery::findOrCreateRange(qbdsPurchTable,fieldNum(PurchTable,PurchStatus));
    qbr.value(queryValue(PurchStatus::Backorder));
    qbds                = qbdsPurchTable.addDataSource(tableNum(PurchLine));
    qbds.joinMode(joinMode::NoExistsJoin);
    qbds.fetchMode(QueryFetchMode::One2One);
    qbds.relations(true);
    qbr                 = sysQuery::findOrCreateRange(qbds,fieldNum(PurchLine,ItemId));
    qbr.value(queryValue(#itemIdParm));
    qbr                 = sysQuery::findOrCreateRange(qbds,fieldNum(PurchLine,RecId));
    qbr.value(strFmt('((%1.%2 != "%3") || (%4.%5 == "%5"))',
                        qbds.name(),
                        fieldId2name(tableNum(PurchLine),fieldNum(PurchLine,PurchStatus)),
                        queryValue(PurchStatus::Backorder),
                        qbds.name(),
                        fieldId2name(tableNum(PurchLine),fieldNum(PurchLine,Blocked)),
                        queryValue(NoYes::Yes)
                     )
             )       ;
    info(qbdsPurchLineSum.toString());
    qr              = new QueryRun(q);
    while (qr.next())
    {
        PurchLine       = qr.get(PurchLine.TableId);
        info(strFmt("%1 %2",PurchLine.PurchId,PurchLine.PurchQty));
    }
}

примерно так (4.0 в т.ч.)

[Evgeniy2020]

2 Titiov:

спасибо подход правильный, только немного не правильный получается запрос и естественно ничего не возвращает, хотя запись есть.
это из за того что получается вот такой запрос

PurchLine PurchLine;
PurchLine PurchLine_1_1;
PurchTable PurchTable;
;
while SELECT SUM(PurchQty) FROM PurchLine
WHERE ((PurchLine.PurchStatus == 1))
&& ((PurchLine.ItemId == 'ФТ-018'))
EXISTS JOIN * FROM PurchTable
WHERE PurchLine.PurchId == PurchTable.PurchId && ((PurchTable.PurchStatus == 1))
NOTEXISTS JOIN * FROM PurchLine
WHERE PurchTable.PurchId ==
PurchLine.PurchId && ((PurchLine.ItemId == 'ФТ-018'))
&& ((((PurchLine_1_1.PurchStatus != 1)
|| (PurchLine_1_1.Blocked == 1))))
{
info('1');
}


если ручками потредактировать то вот такой запрос возвращает данные


PurchLine PurchLine;
PurchLine PurchLine_1_1;
PurchTable PurchTable;
;
while SELECT SUM(PurchQty) FROM PurchLine
WHERE ((PurchLine.PurchStatus == 1))
&& ((PurchLine.ItemId == 'ФТ-018'))
EXISTS JOIN * FROM PurchTable
WHERE PurchLine.PurchId == PurchTable.PurchId && ((PurchTable.PurchStatus == 1))
NOTEXISTS JOIN * FROM PurchLine_1_1
WHERE PurchTable.PurchId ==
PurchLine_1_1.PurchId && ((PurchLine_1_1.ItemId == 'ФТ-018'))
&& ((((PurchLine_1_1.PurchStatus != 1)
|| (PurchLine_1_1.Blocked == 1))))
{
info('1');
}


а как эти изменения внести в код Query который указан выше (предыдущий пост) ?

[titov]

Цитата:

Сообщение от Evgeniy2020

а как эти изменения внести в код Query который указан выше (предыдущий пост) ?

никак - упустил такой момент - две одинаковые таблицы
стандартно не знаю способа, да и нет кажется
но есть один "хитрый" путь
создать вьюху PurchLineView1 с полями PurchId, PurchStatus, Blocked, RecId1, ItemId и в моем джобе сделать так

PHP код:

    qbds                = qbdsPurchTable.addDataSource(tableNum(PurchLineView1));
    qbds.joinMode(joinMode::NoExistsJoin);
    qbds.fetchMode(QueryFetchMode::One2One);
    qbds.relations(true);
    qbr                 = sysQuery::findOrCreateRange(qbds,fieldNum(PurchLineView1,ItemId));
    qbr.value(queryValue(#itemIdParm));
    qbr                 = sysQuery::findOrCreateRange(qbds,fieldNum(PurchLineView1,RecId));
    qbr.value(strFmt('((%1.%2 != "%3") || (%4.%5 == "%5"))',
                        qbds.name(),
                        fieldId2name(tableNum(PurchLineView1),fieldNum(PurchLineView1,PurchStatus)),
                        queryValue(PurchStatus::Backorder),
                        qbds.name(),
                        fieldId2name(tableNum(PurchLineView1),fieldNum(PurchLineView1,Blocked)),
                        queryValue(NoYes::Yes)
                     )
             )       ; 


иногда очень, очень редко пользуюсь, если "ооочень" надо

[vanokh]

Цитата:

Сообщение от titov

никак - упустил такой момент - две одинаковые таблицы
стандартно не знаю способа, да и нет кажется

почему же, есть способ - вторым параметром указываете имя таблицы:

qbds = qbdsPurchTable.addDataSource(tableNum(PurchLine), 'PurchLine_1_1');

потом берете в условии qbds.name()

[titov]

Цитата:

Сообщение от vanokh

почему же, есть способ - вторым параметром указываете имя таблицы:

qbds = qbdsPurchTable.addDataSource(tableNum(PurchLine), 'PurchLine_1_1');

потом берете в условии qbds.name()

qbds.name() действительно вернет то, что нужно.
Но речь о том, что возвращает info(qbdsPurchLineSum.toString());
а именно:
SELECT SUM(PurchQty) FROM PurchLine WHERE ((PurchStatus = 1)) AND ((ItemId = N'123')) EXISTS JOIN * FROM PurchTable WHERE PurchLine.PurchId = PurchTable.PurchId AND ((PurchStatus = 1)) NOTEXISTS JOIN * FROM PurchLine WHERE PurchTable.PurchId = PurchLine.PurchId AND ((ItemId = N'123')) AND ((((PurchLine_1_1.PurchStatus != 1) || (PurchLine_1_1.Blocked == 1))))
даже если применить qbds = qbdsPurchTable.addDataSource(tableNum(PurchLine), 'PurchLine_1_1');
4.0 и ах2009

[S.Kuskov]

Цитата:

Сообщение от titov

Но речь о том, что возвращает info(qbdsPurchLineSum.toString());

Это проблема только отображения текста запроса. Выполняться всё равно будет правильный запрос.

[Evgeniy2020]

ну сам запрос получился лучше с View и как запрос select отрабатывает правильно, но через Query и QueryRun система не возврщает записи,
значит что то работает не правильно.

да, я мог бы долго мучаться с такими ограничениями, но решил поинтересоваться там где я действительно не пользовался View.

но увы задачу пока что это не решает, хотя я самостоятельно упростил
первоначальное условия выборки.

но пока что цель не достигнута, и я пока не знаю как это сделать в одном запросе, хотя теоритически может и возможно.

а вот QueryRun не возвращает значений на 4-ке почему то не работает и через вьюшку а сам запрос я проверил получается правильный.

так что задачка по прежнему не решена. я лишь пока что убедился,
что в один запрос ее как не решить.

так как даже в такой выборке запрос не вернет тех закупок где строк с такой номенклатурой нет.

так что только двумя запросами знаю как решить, но одним не получается.

[titov]

Цитата:

Сообщение от Evgeniy2020

ну сам запрос получился лучше с View и как запрос select отрабатывает правильно, но через Query и QueryRun система не возврщает записи,
значит что то работает не правильно.

до этого писал только "рыбу" без проверки, важно было направление
ниже "проверенный" код

    qbr.value(strFmt('((%1.%2 != %3) || (%4.%5 == %6))',
                        qbds.name(),
                        fieldId2name(tableNum(PurchLineView1),fieldNum(PurchLineView1,PurchStatus)),
                        enum2int(PurchStatus::Backorder),
                        qbds.name(),
                        fieldId2name(tableNum(PurchLineView1),fieldNum(PurchLineView1,Blocked)),
                        enum2int(NoYes::Yes)
                     )
             )       ;

[S.Kuskov]

Цитата:

Сообщение от Evgeniy2020

PurchLine PurchLine;
PurchLine PurchLine_1_1;
PurchTable PurchTable;
;
while SELECT SUM(PurchQty) FROM PurchLine
WHERE ((PurchLine.PurchStatus == 1))
&& ((PurchLine.ItemId == 'ФТ-018'))
EXISTS JOIN * FROM PurchTable
WHERE PurchLine.PurchId == PurchTable.PurchId && ((PurchTable.PurchStatus == 1))
NOTEXISTS JOIN * FROM PurchLine_1_1
WHERE PurchTable.PurchId ==
PurchLine_1_1.PurchId && ((PurchLine_1_1.ItemId == 'ФТ-018'))
&& ((((PurchLine_1_1.PurchStatus != 1)
|| (PurchLine_1_1.Blocked == 1))))
{
info('1');
}

PurchTable в этом запросе абсолютно лишний. Запрос эквивалентен следующему

PurchLine PurchLine;
PurchLine PurchLine_1_1;
;
while select sum(PurchQty) from PurchLine
where 
    PurchLine.PurchStatus == 1 && PurchLine.ItemId == 'ФТ-018'
notexists join PurchLine_1_1
where 
    PurchLine_1_1.PurchId == PurchLine.PurchId && 
    PurchLine_1_1.ItemId == PurchLine.ItemId && 
   (PurchLine_1_1.PurchStatus != 1 || PurchLine_1_1.Blocked == 1)
{
    info('1');
}