OZKA's DAX Journal: Join между временной и постоянной таблицей через QueryRun.

[Blog bot]

Источник: http://ozka-lemming.blogspot.com/200...-queryrun.html
==============

Однажды, отлаживая нетривиальный код, наткнулся на subj. Не зная про эту «фичу», я долго удивлялся почему запрос возвращает такой странный набор данных!?! Ниже приведен простенький Job-ик, который демонстрирует существование этой возможности в DAX. В иерархии запроса временная таблица должна быть первым источником данных.

static void JoinTmpTablesOnQuery(Args _args)
{
    LedgerTrans             ledgerTrans;
    LedgerTable             ledgerTableTmp;

    int                     i;
    int                     transCnt   = 20;

    Query                   query      = new Query();
    
    QueryBuildDataSource    qbdsTable  = query.addDataSource(tableNum(LedgerTable));
    QueryBuildDataSource    qbds2Trans = qbdsTable.addDataSource(tableNum(LedgerTrans));


    QueryRun                queryRun;
    ;

    qbds2Trans.relations(true);

    ledgerTableTmp.setTmp();
    
    ledgerTableTmp.data(LedgerTable::find("02.010"));
    ledgerTableTmp.insert();
    
    ledgerTableTmp.data(LedgerTable::find("01.030"));
    ledgerTableTmp.insert();
    
    queryRun = new QueryRun(query);

    queryRun.setCursor(ledgerTableTmp, 1);
    
    i = 0;

    while (queryRun.next())
    {
        ledgerTableTmp = queryRun.getNo(1);
        ledgerTrans    = queryRun.getNo(2);

        info(strfmt("AccountNum %1 , AmountCur %2 , (tmpRecId %3 , regRecId %4)",
                     ledgerTableTmp.AccountNum,
                     ledgerTrans.AmountCur,
                     ledgerTableTmp.RecId,
                     ledgerTrans.RecId));
 
        i++;
        
        if (transCnt && i == transCnt)
            break;
    }

}

Источник: http://ozka-lemming.blogspot.com/200...-queryrun.html

[Gustav]

Lemming, а расскажите чуть подробнее и не так загадочно?

Что должно происходить? Я грешным делом подумал, что можно наконец-то полноценно связать временную таблицу с постоянной, т.е. фильтровать постоянную таблицу по временному набору. Но в выводимых результатах что-то этого не заметил...

Спасибо.

[Lemming]

В приведенном джобике(если я конечно не сошел с ума ) запрос LedgerTable и LedgerTrans должен выводить проводки только по тем счетам, которые попали во временную таблицу LedgerTransTmp. (см. queryRun.setCursor(ledgerTableTmp, 1);


Job писал в DAX 4, но должно отработать и в 3-ке(в свое время увидел именно в ней). Или джоб так хитро отрабатывает только у меня?

[ZVV]

Да нет, с queryRun.setCursor действительно работает.. На 3.0 тоже.

[ZVV]

Временные таблицы и query

[Lemming]

Цитата:

Сообщение от ZVV

Временные таблицы и query

Ну да, было дело, спрашивал, а вот то что их можно так хитро заджоинить, временную с постоянной через queryRun, я не знал

upd:

Врочем так тоже можно, хотя это наверное многие знают.

ledgerTableTmp.data(LedgerTable::find("01.030"));
    ledgerTableTmp.insert();
    
    while select ledgerTableTmp
    join ledgerTrans
        where ledgerTrans.AccountNum == ledgerTableTmp.AccountNum
    {
        info(ledgerTrans.AccountNum);
    }
    return;

[Gustav]

Цитата:

Сообщение от Lemming

запрос LedgerTable и LedgerTrans должен выводить проводки только по тем счетам, которые попали во временную таблицу LedgerTransTmp.

Ok, значит я думал правильно и тоже хотел именно этого. Но увы...

Цитата:

Сообщение от ZVV

Да нет, с queryRun.setCursor действительно работает.. На 3.0 тоже.

Получается, не у всех... У меня на 3.0, SP4, двухзвенка, Oracle 10g - НЕ РАБОТАЕТ, вылезает унылое декартово произведение.

[Lemming]

Цитата:

Сообщение от Gustav

Получается, не у всех... У меня на 3.0, SP4, двухзвенка, Oracle 10g - НЕ РАБОТАЕТ, вылезает унылое декартово произведение.

Оракле под рукой увы нет...Кстати, я только что проверил и спокойно, как через qr, так и через Хрр смог две временных поджоинить. А вот временную с постоянной, когда постоянная идет "вверху" запроса

while select ledgerTrans
    join ledgerTableTmp
        where ledgerTableTmp.AccountNum == ledgerTrans.AccountNum
    {
        info(ledgerTransTmp.AccountNum);
    }
    return;

приводит к известной многим ошибке : "Временные таблицы должны быть вложенными при объединении с постоянными таблицами."

[ZVV]

Цитата:

Сообщение от Gustav

Получается, не у всех... У меня на 3.0, SP4, двухзвенка, Oracle 10g - НЕ РАБОТАЕТ, вылезает унылое декартово произведение.

3.0 sp3 kr3 Oracle9i - работает вероятно дело именно в KR?

Цитата:

Сообщение от Lemming

Врочем так тоже можно, хотя это наверное многие знают.

ledgerTableTmp.data(LedgerTable::find("01.030"));
    ledgerTableTmp.insert();
    
    while select ledgerTableTmp
    join ledgerTrans
        where ledgerTrans.AccountNum == ledgerTableTmp.AccountNum
    {
        info(ledgerTrans.AccountNum);
    }
    return;

А вот так не работает, так декартово произведение..
Или что вы тут хотели сказать?

[ZVV]

Цитата:

Сообщение от Lemming

А вот временную с постоянной, когда постоянная идет "вверху" запроса

while select ledgerTrans
    join ledgerTableTmp
        where ledgerTableTmp.AccountNum == ledgerTrans.AccountNum
    {
        info(ledgerTransTmp.AccountNum);
    }
    return;

приводит к известной многим ошибке : "Временные таблицы должны быть вложенными при объединении с постоянными таблицами."

Кстати говоря и вот это на указанной выше конфигурации никакой ошибки не выдаёт... Банальное декартово произведение.

[Lemming]

Цитата:

Сообщение от ZVV

А вот так не работает, так декартово произведение..
Или что вы тут хотели сказать?

У меня отработало аналогично джобу из оригинального поста. В общем, в любом раскладе, судя по такой неустойчивости к версиям и СУБД, лучше не забавляться с такими связками в реальных проектах.

[ZVV]

Цитата:

Сообщение от Lemming

У меня отработало аналогично джобу из оригинального поста. В общем, в любом раскладе, судя по такой неустойчивости к версиям и СУБД, лучше не забавляться с такими связками в реальных проектах.

Да, это точно!

Ещё прикол:

     i = 0;

    while select ledgerTableTmp
    join ledgerTrans
        where ledgerTrans.AccountNum == ledgerTableTmp.AccountNum
    {
        info('1:' + ledgerTrans.AccountNum);
        i++;

        if (transCnt && i == transCnt)
            break;
    }

    i = 0;

    while select ledgerTrans
    join ledgerTableTmp
        where ledgerTrans.AccountNum == ledgerTableTmp.AccountNum
    {
        info('2:' + ledgerTrans.AccountNum);
        i++;

        if (transCnt && i == transCnt)
            break;
    }

    i = 0;

    while select ledgerTableTmp
    join ledgerTrans
        where ledgerTrans.AccountNum == ledgerTableTmp.AccountNum
    {
        info('3:' + ledgerTrans.AccountNum);
        i++;

        if (transCnt && i == transCnt)
            break;
    }

1 и 3 - одинаковые.

При этом 1 посылает к СУБД запрос (гы ) следующего вида:

PHP код:

SELECT ...FROM LEDGERTRANS A WHERE ((SUBSTR(NLS_LOWER(DATAAREAID),1,3)=NLS_LOWER(:in1)/*'mil'*/) AND (SUBSTR(NLS_LOWER(ACCOUNTNUM),1,10)=SUBSTR(NLS_LOWER(ACCOUNTNUM),1,10))) 


(т.е. на самом деле не совсем декартово произведение, а вообще просто выборка из LedgerTrans, без учёта нашей временной таблицы)
2 - делает нормальное декартово произведение
3 - не выполняется вообще (ни запроса, ни инфо)! (именно после выполнения 2, т.к. 1 - выполняется)
15 мин. голову ломал... бред какой-то...

[Lemming]

Цитата:

Сообщение от ZVV

3 - не выполняется вообще (ни запроса, ни инфо)! (именно после выполнения 2, т.к. 1 - выполняется)
15 мин. голову ломал... бред какой-то...

Опа, точно! Я тоже наткнулся на подобное - вроде только что работало, а тут бамс и перестало. Переключил еще раз компанию, в которой у меня правильные для теста счета были(хотя в ней и был), отработало. Судя по всему, жутко неустойчивая фича.