2 и более OUTER JOIN к одному паренту

[Ronin]

Доброго времени суток, вам, господа и дамы!

Не подскажите, как построить селект с 2мя и более outer join'ами с одним парентом? Или объяснить мне в чем я не прав.

У меня на последнем Join'e ругается что

"Невозможно выбрать запись в 'Условия оплаты' ('PaymTerm')
Использован оператор объединения таблиц join, но выражение WHERE не содержит связи между таблицами."

static void Job10(Args _args)
{
SalesTable contractTable;
EmplTable emplTable;
PaymTerm paymTerm;
;

while
select SalesName
from contractTable

outer join NumOfDays, Description
from paymTerm
where paymTerm.PaymTermId == contractTable.Payment

outer join Name
from emplTable
where emplTable.EmplId == contractTable.SalesResponsible

{
info(strfmt("%1 %2", paymTerm.NumOfDays, contractTable.SalesName));
}

}

Хинт: с "обыкновенными", inner join'ами, все job запускается...

[db]

Это глюк ядра, а точнее парсера запросов. В сервисную систему регистрировал, когда исправят не знаю.
хинт: если не хотите ждать, то используйте в качестве СУБД Oracle - парсер запросов для него отрабатывает корректно

[mazzy]

Цитата:

Изначально опубликовано db
хинт: если не хотите ждать, то используйте...

Или query. см.руководство разработчика. ключевое слово "Sequencing of retrieved records"

[Ronin]

Спасибо всем за ответ!

db: на счет Oracle - узнать это было интересно, особенно в конетксте наличия подводных камней при переносе базы с одной платформы на другую.

Mazzy: с помощью query задача и решилась, причем еще до написания поста. Просто этот случай своей нелепостью вызывал уже чисто академический интерес: как можно в конструкции select сделать более 1го outer join, и если нельзя, то почему.

Ответы я похоже получил исчерпывающие.
Спасибо.
:-)

[mazzy]

awas, в ФАК этот ответ заносить стоит?

[Ronin]

ИМХО: однозначно.

[mazzy]

сделано http://forum.mazzy.ru/index.php?showtopic=2454

[Wamr]

Цитата:

Или query

Вот это я не понял...

PHP код:

static void Job40(Args _args)
{
    Query       q = new Query();
    QueryRun    qr;
    QueryBuildDataSource qbDS1, qbDS2;
    ;

    qbDS1 = q.addDataSource(tableNum(InventSum));

    qbDS2 = qbDS1.addDataSource(tableNum(InventTable));
    qbDS2.joinMode(JoinMode::OuterJoin);
    qbDS2.fetchMode(QueryFetchMode::One2One);
    qbDS2.relations(true);

    qbDS2 = qbDS1.addDataSource(tableNum(InventDim));
    qbDS2.joinMode(JoinMode::OuterJoin);
    qbDS2.fetchMode(QueryFetchMode::One2One);
    qbDS2.relations(true);

    info(qbDS1.toString());

    qr = new QueryRun(q);
    qr.next();
} 


Невозможно выбрать запись в 'Складская аналитика' ('InventDim')
Использован оператор объединения таблиц join, но выражение WHERE не содержит связи между таблицами.

[Ronin]

Еще в копилку.

Немного интересного обнаружил при анализе одного запроса с помощью профайлера.
Запрос имеет примерно следующую структуру:

select Table_1
inner join Table_2
outer join Table_2_1
outer join Table _2_1_1
outer join Table_2_2
outer join Table_2_2_1

Аксапта этот запрос разбила на 3...

Этот выполнялся соответственно 1 раз
select Table_1
join Table_2


Эти части выполнялись соответственно столько раз, сколько записей вернулось при 1 запросе...

select Table_2_1
outer join Table _2_1_1

select join Table_2_2
outer join Table_2_2_1

При этом на n-ой записи метод queryRun.next() выдает ошибку типа:
"Невозможно выбрать запись в 'Table_2_2_1' ('Table_2_2_1')
Из базы данных выбрано нулевое значение (NULL), которое не поддерживается."

[Sanya]

С помощью query задача решается не корректно.
Пример запроса:
Таблица 1
outer joun Таблица 2
outer joun Таблица 3

В таблице 1 - 1-а запись
В таблице 2 - 0 - записей
В таблице 3 - 1-а запись связанная с таблицей 1
Цикл по такому запросу сделает 2 итерации:
на 1-ой: Таблица 1 инициализирована
Таблица 2 не инициализирована(оно и понятно в ней нет записей)
Таблица 3 не инициализирована(!!!)

на 2-ой: Таблица 1 инициализирована
Таблица 2 не инициализирована(оно и понятно в ней нет записей)
Таблица 3 инициализирована
Проект в приатацином файле.

Пока только один вариант решения, разбивать запрос на 2.

[vallys]

Строить такие запросы (2 и более OUTER JOIN к одному паренту) на Х++ для таблиц со свойством "SaveDataPerCompany" == "Yes" можно путем добавления фиктивной связи между дочерними таблицами по полю DataAreaId:

PHP код:

ChildTable2.DataAreaId == ChildTable1.DataAreaId || ChildTable2.DataAreaId != ChildTable1.DataAreaId 


Например, запрос из первого сообщения примет вид:

PHP код:

while
select SalesName
from contractTable

outer join NumOfDays, Description
from paymTerm
where paymTerm.PaymTermId == contractTable.Payment

outer join Name
from emplTable
where (emplTable.DataAreaId == paymTerm.DataAreaId || emplTable.DataAreaId != paymTerm.DataAreaId) &&
emplTable.EmplId == contractTable.SalesResponsible 


Это, естественно, добавит работы парсеру SQL-сервера, но т.к. поле DataAreaId входит во все индексы таблиц со свойством "SaveDataPerCompany" == "Yes", то никаких побочных эффектов (кроме пренебрежимо малого падения скорости) быть не должно.

Аналогично для Query, если у вложенных датасоурсов свойство "FetchMode" == "1:1".

[Logger]

Цитата:

Вот это я не понял...

Wamr, я недавно тоже столкнулся с подобным поведением автоджоина. Причем глючило только в случае если на InventDim не было ни одного Range. Стоило добавить хоть один range как все работало хорошо.

Я решил эту проблему
qbDS2.relations(false);
qbDS2.addLink(fieldNum(InventSum, InventDimId), fieldNum(InventDim, InventDimId))

т.е. явным прописыванием связи между таблицами...

[Perc]

Цитата:

Сообщение от vallys

Аналогично для Query, если у вложенных датасоурсов свойство "FetchMode" == "1:1".

vallys здорово придумано с select, но вот "аналогично для Query" я не понимаю как составить связь. Всяко вертел пример Wamr, но что то он у меня так и не заработал. Не могли бы приставить необходимые строчки?

[Perc]

Цитата:

Сообщение от Logger

Wamr, я недавно тоже столкнулся с подобным поведением автоджоина. Причем глючило только в случае если на InventDim не было ни одного Range. Стоило добавить хоть один range как все работало хорошо.

Я решил эту проблему
qbDS2.relations(false);
qbDS2.addLink(fieldNum(InventSum, InventDimId), fieldNum(InventDim, InventDimId))

т.е. явным прописыванием связи между таблицами...

Переписывал пример с учетом замечаний Logger, но исходная ошибка не исчезает.

И к awas вопрос - как ему совет mazzy помог? Я тоже посмотрел те картинки, но решения проблемы оттуда не увидел. Может у вас просто query на автомате создался со свойстовом "FetchMode" == "1:n" на датасорсе и дело двинулось по другому пути? но исходная проблема не решилась?

[AndyD]

Попробуйте так

    qbDS2.relations(false);                
    qbDS2.addRange(fieldNum(InventDim, InventDimId)).
        value(strfmt("(((%2.dataAreaId == %3.DataAreaId) || (%2.dataAreaId != %3.DataAreaId)) && " +
                     "(%1.inventDimId == %3.inventDimId))",
                        qbDS1.name(), 
                        q.dataSourceTable(tableNum(InventTable)).name(), 
                        qbDS2.name()));

[Perc]

Цитата:

Сообщение от AndyD

Попробуйте так

    qbDS2.relations(false);                
    qbDS2.addRange(fieldNum(InventDim, InventDimId)).
        value(strfmt("(((%2.dataAreaId == %3.DataAreaId) || (%2.dataAreaId != %3.DataAreaId)) && " +
                     "(%1.inventDimId == %3.inventDimId))",
                        qbDS1.name(), 
                        q.dataSourceTable(tableNum(InventTable)).name(), 
                        qbDS2.name()));

Спсб AndyD. Наставил на путь истинный. Я делал почти тоже самое, но наивно решил не заморачиваться с strfmt() в тесте своем и вбивал сразу же условие текстом

    qbDS2.addRange(fieldNum(InventDim, InventDimId)).
        value("(((InventTable.dataAreaId == InventDim.DataAreaId) || (InventTable.dataAreaId != InventDim.DataAreaId)) && (InventSum.inventDimId == InventDim.inventDimId))");

вот это меня и подвело. Ни разу даже мысли не возникло проверить что за текст там получается и как на самом деле датасорсы называются.
Не ошибайтесь так люди

[AndyD]

Можно было явно дать название датасоурсам

qbDS1 = q.addDataSource(tableNum(InventSum), "InventSum");
или qbDS1.Name("InventSum");
и т.д.
Тогда бы ваш вариант работал.

[Wamr]

Хочу отметить, что Job40 (см. тут ) замечательно работает на Oracle и никак не работает на MS SQL.

[vallys]

Цитата:

Сообщение от Wamr

Хочу отметить, что Job40 (см. тут ) замечательно работает на Oracle и никак не работает на MS SQL.

Если перед info добавить

qbDS2.addRange(fieldnum(InventDim, DataAreaId)).value(strfmt(
        "((%1.DataAreaId == %2.DataAreaId) || (%1.DataAreaId != %2.DataAreaId))",
        qbDS2.name(),
        q.dataSourceTable(tablenum(InventTable)).name()
        ));

то и на MS SQL заработает

[Wamr]

а включаешь

PHP код:

    qbDS2 = qbDS1.addDataSource(tableNum(InventDim));
    qbDS2.joinMode(JoinMode::OuterJoin);
    qbDS2.fetchMode(QueryFetchMode::One2One);
    qbDS2.relations(true);
//    qbDS2.addLink(fieldNum(InventSum, InventDimId), fieldNum(InventDim, InventDimId));
    qbDS2.addRange(fieldnum(InventDim, DataAreaId)).value(strfmt(
        "((%1.DataAreaId == %2.DataAreaId) || (%1.DataAreaId != %2.DataAreaId))",
        qbDS2.name(),
        q.dataSourceTable(tablenum(InventTable)).name()
        )); 


- не работает
Наверно, это из-за SaveDataPerCompany = NO