void ChangeLifeTime()
{
    DialogRunBase           dialog = new Dialog();
    DialogField             dialogDate,dialogLifeTime,dialogStandardId;

    RAssetLifeTime          dialogLifeTimeValue;
    RAssetStandardId        dialogStandardValue;
    TransDate               dialogDateValue;
    int                     i = 0;
    common                  urRec;
    RassetTable             urRAssetTable;
    RassetStandards         urRassetStandards;

    DialogGroup             dialogGroupSS;  // группа, в которую помещается Spreadsheet
    FormGroupControl        groupSS;        // та же группа, только уже как контрол
    FormActiveXControl      ss;             // собственно Spreadsheet

    COM                     range;
    COM                     temp;
    COM                     currCell;
    COMVariant              cv;

    int                     lastRow;
    int                     row;

    RassetId                currRassetId;
    RAssetLifeTime          currLifeTime;

    ;
    urRec = RAssetTable_ds.getFirst(1);
    if (! urRec) urRec = RAssetTable_ds.cursor();
    if (urRec)
    {
        dialog.caption("Новые значения");

        // KKu, 22.09.2009 --> модификация на случай разных сроков службы
        dialog.addGroup('Основные параметры');
        // KKu, 22.09.2009 <--

        DialogDate = dialog.addField(typeId(TransDate));
        DialogDate.value(today());
        dialogStandardId = dialog.addField(typeId(RAssetStandardId));
        dialogLifeTime = dialog.addField(typeId(RAssetLifeTime));

        dialogDate.widthMode(formwidth::ColumnWidth);
        dialogStandardId.widthMode(formwidth::ColumnWidth);
        dialogLifeTime.widthMode(formwidth::ColumnWidth);

        // KKu, 22.09.2009 --> модификация на случай разных сроков службы
        // без группы Spreadsheet показывался неуправляемо
        // только при помощи группы он более-менее обуздался
        dialogGroupSS = dialog.addGroup('В случае разных сроков службы');
        groupSS = dialogGroupSS.formGroup();
        groupSS.addControl(FormControlType::ActiveX, 'MySpreadSheet');

        dialog.doInit();

        ss = dialog.formRun().design().controlName('MySpreadSheet');
        ss.className('{0002E541-0000-0000-C000-000000000046}');     // Microsoft Office Spreadsheet 10.0
        //ss.className('{0002E559-0000-0000-C000-000000000046}');   // Microsoft Office Spreadsheet 11.0

        ss.height(300);
        ss.width(600);

        // гасим ярлычки листов
        ss.DisplayWorkbookTabs(false);

        range = ss.Range('A1'); range.Value2('Инв. номер ОС');
        range = ss.Range('B1'); range.Value2('Новый срок службы');
        range = ss.Range('C1'); range.Value2('Инструкция');

        range = ss.Range('C2'); range.Value2('Если Вы хотите выполнить обновление');
        range = ss.Range('C3'); range.Value2('сроков службы для нескольких ОС');
        range = ss.Range('C4'); range.Value2('разными значениями сроков,');
        range = ss.Range('C5'); range.Value2('то поставьте "Срок службы" равным -1');
        range = ss.Range('C6'); range.Value2('в группе полей "Основные параметры"');
        range = ss.Range('C7'); range.Value2('и введите данные в колонки A и B,');
        range = ss.Range('C8'); range.Value2('начиная со строки 2.');

        range = ss.Range('A1:C1');
        temp = range.Font();
        temp.Bold(true);

        temp = range.EntireColumn();
        temp.AutoFit();
        // KKu, 22.09.2009 <--

        if (dialog.run())
        {
            dialogDateValue =           DialogDate.value();
            dialogStandardValue =       dialogStandardId.value();
            dialogLifeTimeValue =       dialogLifeTime.value();
            if (! (dialogDateValue && dialogStandardValue && dialogLifeTimeValue))
            {
                checkFailed(strFmt("Заполните все поля"));
                return;
            }
            if (! RAssetStandardTable::Find(dialogStandardValue))
            {
                checkFailed(strFmt("Значение '%1' не найдено в таблице модели учета", dialogStandardValue));
                return;
            }

            // KKu, 22.09.2009 --> модификация на случай разных сроков службы
            if (dialogLifeTimeValue != -1)
            // KKu, 22.09.2009 <--
            {
                // старое продолжение
                While (urRec)
                {
                    i++;
                    RAssetTable_ds.findRecord(urRec);
                    if (RAssetTable_ds)
                    {
                        historyDialog.lifetimeDate(dialogDateValue);
                        ttsBegin;
                        urRassetStandards = RassetStandards::find(
                            urRec.(fieldNum(RAssetTable,AccountNum)),dialogStandardValue, true);
                        urRassetStandards.Lifetime = dialogLifeTimeValue;
                        urRassetStandards.update(historyDialog);
                        ttsCommit;
                        RAssetTable_ds.reread();
                        RAssetTable_ds.refresh();
                    }

                    urRec = RAssetTable_ds.getNext();
                }
            }
            // KKu, 22.09.2009 --> модификация на случай разных сроков службы
            else
            {
                // новое продолжение

                // определяем последнюю строку
                lastRow = xlRanges::countRows(range.CurrentRegion());

                for (row=2; row <=lastRow; row++)
                {
                    // читаем из Spreadsheet Инв.номер ОС
                    currCell = xlRanges::cellRC(range, row, 1, true);
                    cv = currCell.Value();
                    currRassetId = cv.bStr();

                    // читаем из Spreadsheet Новый срок службы
                    currCell = xlRanges::cellRC(range, row, 2, true);
                    cv = currCell.Value();
                    currLifeTime = cv.double();

                    urRAssetTable = RAssetTable::find(currRassetId);
                    if (urRAssetTable)
                    {
                        i++;
                        historyDialog.lifetimeDate(dialogDateValue);
                        ttsBegin;
                        urRassetStandards = RassetStandards::find(
                            urRAssetTable.AccountNum, dialogStandardValue, true);
                        urRassetStandards.Lifetime = currLifeTime; // dialogLifeTimeValue;
                        urRassetStandards.update(historyDialog);
                        ttsCommit;
                        info(strFmt('%1 --- %2', currRassetId, currLifeTime));
                    }
                }
            }
            // KKu, 22.09.2009 <--

            info(strFmt("Операция по смене срока службы по %1 ОС  модели %2 успешно завершена", int2Str(i),dialogStandardValue));
        }
    }
}

static int countRows(COM parentRange)
{
    // COM parentRange может быть Excel.Application (подразумевается ActiveSheet) или Worksheet или Range
    // в случае Spreadsheet - Spreadsheet.Application или Worksheet или Range

    return any2int(COM::createFromObject( parentRange.Rows() ).Count());
}

static COM cellRC(COM parentRange, int row, int col, boolean forSpreadsheet = false)
{
    // COM parentRange может быть Excel.Application (подразумевается ActiveSheet) или Worksheet или Range
    // в случае Spreadsheet - Spreadsheet.Application или Worksheet или Range
    // row и col могут быть меньше единицы (0 и отрицательные) - и для Excel, и для Spreadsheet
    // но меньше единицы - только для Range (не для Application, и не для Worksheet)
    // возвращает объект Range
    COM cells;
    ;
    cells = parentRange.Cells();

    if (! forSpreadsheet)
        // Excel
        return COM::createFromVariant( cells.Item( row, col ));
    else
        // Spreadsheet
        return cells.Item( row, col );
}

// для того, чтобы первичная группа пользователя
// менялась по кругу при очередном щелчке
public int mouseDblClick(int _x, int _y, int _button, boolean _Ctrl, boolean _Shift)
{
    int                 ret;
    str                 groupToFind;
    container           filials = ['Head','Branch1','Branch2',''];
    int                 pos;

    ret = super(_x, _y, _button, _Ctrl, _Shift);

    groupToFind = SysUserInfo.UserGroupDim;
    pos = conFind(filials, groupToFind);
    pos++;
    if (pos > conLen(filials)) pos = 1;

    SysUserInfo.UserGroupDim = conPeek(filials, pos);
    SysUserInfo.write();
    SysUserInfo_ds.reread();
    SysUserInfo_ds.refresh();

    return ret;
}

/* %1 holiday exceptions map  */

#LOCALMACRO.holidayExceptionsInsert
    // ФОРМИРОВАНИЕ СПИСКА ИСКЛЮЧЕНИЙ - на основании Постановлений Правительства РФ

    // В соответствии c Постановлением Правительства РФ от 11 ноября 2006 года N 661
    // переносятся следующие выходные дни 2007 года

    // с субботы 28 апреля на понедельник 30 апреля
    %1.insert( 28\04\2007, 2);  // 2 - т.к. перенос с предпраздничного дня
    %1.insert( 30\04\2007, 0);

    // с субботы 9 июня на понедельник 11 июня
    %1.insert( 09\06\2007, 2); // 2 - т.к. перенос с предпраздничного дня
    %1.insert( 11\06\2007, 0);

    // с субботы 29 декабря на понедельник 31 декабря
    %1.insert( 29\12\2007, 2);  // 2 - т.к. перенос с предпраздничного дня
    %1.insert( 31\12\2007, 0);


    // В соответствии с Постановлением Правительства РФ от 11.08.2007 № 512
    // переносятся следующие выходные дни 2008 года:

    // с воскресенья 4 мая на пятницу 2 мая
    %1.insert( 04\05\2008, 1); //  4 мая 2008 стал рабочим днем
    %1.insert( 02\05\2008, 0); //  2 мая 2008 стал выходным днем

    // с субботы 7 июня на пятницу 13 июня
    %1.insert( 07\06\2008, 1); //  7 июня 2008 стал рабочим днем
    %1.insert( 13\06\2008, 0); // 13 июня 2008 стал выходным днем

    // с субботы 1 ноября на понедельник 3 ноября
    %1.insert( 01\11\2008, 2); //  // 2 - т.к. перенос с предпраздничного дня
    %1.insert( 03\11\2008, 0); //


    // В соответствии c Постановлением Правительства от 26.11.2008 № 877
    // переносятся следующие выходные дни 2009 года:

    // с воскресенья 11 января на пятницу 9 января.
    %1.insert( 11\01\2009, 1);
    %1.insert( 09\01\2009, 0);
#ENDMACRO